dyn.lds.S 5.3 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181
  1. #include <asm/vmlinux.lds.h>
  2. #include <asm/page.h>
  3. OUTPUT_FORMAT(ELF_FORMAT)
  4. OUTPUT_ARCH(ELF_ARCH)
  5. ENTRY(_start)
  6. jiffies = jiffies_64;
  7. VERSION {
  8. {
  9. local: *;
  10. };
  11. }
  12. SECTIONS
  13. {
  14. PROVIDE (__executable_start = START);
  15. . = START + SIZEOF_HEADERS;
  16. .interp : { *(.interp) }
  17. __binary_start = .;
  18. . = ALIGN(4096); /* Init code and data */
  19. _text = .;
  20. INIT_TEXT_SECTION(PAGE_SIZE)
  21. . = ALIGN(PAGE_SIZE);
  22. /* Read-only sections, merged into text segment: */
  23. .hash : { *(.hash) }
  24. .gnu.hash : { *(.gnu.hash) }
  25. .dynsym : { *(.dynsym) }
  26. .dynstr : { *(.dynstr) }
  27. .gnu.version : { *(.gnu.version) }
  28. .gnu.version_d : { *(.gnu.version_d) }
  29. .gnu.version_r : { *(.gnu.version_r) }
  30. .rel.init : { *(.rel.init) }
  31. .rela.init : { *(.rela.init) }
  32. .rel.text : { *(.rel.text .rel.text.* .rel.gnu.linkonce.t.*) }
  33. .rela.text : { *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*) }
  34. .rel.fini : { *(.rel.fini) }
  35. .rela.fini : { *(.rela.fini) }
  36. .rel.rodata : { *(.rel.rodata .rel.rodata.* .rel.gnu.linkonce.r.*) }
  37. .rela.rodata : { *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*) }
  38. .rel.data : { *(.rel.data .rel.data.* .rel.gnu.linkonce.d.*) }
  39. .rela.data : { *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*) }
  40. .rel.tdata : { *(.rel.tdata .rel.tdata.* .rel.gnu.linkonce.td.*) }
  41. .rela.tdata : { *(.rela.tdata .rela.tdata.* .rela.gnu.linkonce.td.*) }
  42. .rel.tbss : { *(.rel.tbss .rel.tbss.* .rel.gnu.linkonce.tb.*) }
  43. .rela.tbss : { *(.rela.tbss .rela.tbss.* .rela.gnu.linkonce.tb.*) }
  44. .rel.ctors : { *(.rel.ctors) }
  45. .rela.ctors : { *(.rela.ctors) }
  46. .rel.dtors : { *(.rel.dtors) }
  47. .rela.dtors : { *(.rela.dtors) }
  48. .rel.got : { *(.rel.got) }
  49. .rela.got : { *(.rela.got) }
  50. .rel.bss : { *(.rel.bss .rel.bss.* .rel.gnu.linkonce.b.*) }
  51. .rela.bss : { *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*) }
  52. .rel.plt : {
  53. *(.rel.plt)
  54. PROVIDE_HIDDEN(__rel_iplt_start = .);
  55. *(.rel.iplt)
  56. PROVIDE_HIDDEN(__rel_iplt_end = .);
  57. }
  58. .rela.plt : {
  59. *(.rela.plt)
  60. PROVIDE_HIDDEN(__rela_iplt_start = .);
  61. *(.rela.iplt)
  62. PROVIDE_HIDDEN(__rela_iplt_end = .);
  63. }
  64. .init : {
  65. KEEP (*(.init))
  66. } =0x90909090
  67. .plt : { *(.plt) }
  68. .text : {
  69. _stext = .;
  70. TEXT_TEXT
  71. SCHED_TEXT
  72. CPUIDLE_TEXT
  73. LOCK_TEXT
  74. IRQENTRY_TEXT
  75. SOFTIRQENTRY_TEXT
  76. *(.fixup)
  77. *(.stub .text.* .gnu.linkonce.t.*)
  78. /* .gnu.warning sections are handled specially by elf32.em. */
  79. *(.gnu.warning)
  80. . = ALIGN(PAGE_SIZE);
  81. } =0x90909090
  82. . = ALIGN(PAGE_SIZE);
  83. .syscall_stub : {
  84. __syscall_stub_start = .;
  85. *(.__syscall_stub*)
  86. __syscall_stub_end = .;
  87. }
  88. .fini : {
  89. KEEP (*(.fini))
  90. } =0x90909090
  91. .kstrtab : { *(.kstrtab) }
  92. #include <asm/common.lds.S>
  93. __init_begin = .;
  94. init.data : { INIT_DATA }
  95. __init_end = .;
  96. /* Ensure the __preinit_array_start label is properly aligned. We
  97. could instead move the label definition inside the section, but
  98. the linker would then create the section even if it turns out to
  99. be empty, which isn't pretty. */
  100. . = ALIGN(32 / 8);
  101. .preinit_array : { *(.preinit_array) }
  102. .init_array : {
  103. *(.kasan_init)
  104. *(.init_array.*)
  105. *(.init_array)
  106. }
  107. .fini_array : { *(.fini_array) }
  108. .data : {
  109. INIT_TASK_DATA(KERNEL_STACK_SIZE)
  110. . = ALIGN(KERNEL_STACK_SIZE);
  111. *(.data..init_irqstack)
  112. DATA_DATA
  113. *(.data.* .gnu.linkonce.d.*)
  114. SORT(CONSTRUCTORS)
  115. }
  116. .data1 : { *(.data1) }
  117. .tdata : { *(.tdata .tdata.* .gnu.linkonce.td.*) }
  118. .tbss : { *(.tbss .tbss.* .gnu.linkonce.tb.*) *(.tcommon) }
  119. .eh_frame : { KEEP (*(.eh_frame)) }
  120. .gcc_except_table : { *(.gcc_except_table) }
  121. .dynamic : { *(.dynamic) }
  122. .ctors : {
  123. /* gcc uses crtbegin.o to find the start of
  124. the constructors, so we make sure it is
  125. first. Because this is a wildcard, it
  126. doesn't matter if the user does not
  127. actually link against crtbegin.o; the
  128. linker won't look for a file to match a
  129. wildcard. The wildcard also means that it
  130. doesn't matter which directory crtbegin.o
  131. is in. */
  132. KEEP (*crtbegin.o(.ctors))
  133. /* We don't want to include the .ctor section from
  134. from the crtend.o file until after the sorted ctors.
  135. The .ctor section from the crtend file contains the
  136. end of ctors marker and it must be last */
  137. KEEP (*(EXCLUDE_FILE (*crtend.o ) .ctors))
  138. KEEP (*(SORT(.ctors.*)))
  139. KEEP (*(.ctors))
  140. }
  141. .dtors : {
  142. KEEP (*crtbegin.o(.dtors))
  143. KEEP (*(EXCLUDE_FILE (*crtend.o ) .dtors))
  144. KEEP (*(SORT(.dtors.*)))
  145. KEEP (*(.dtors))
  146. }
  147. .jcr : { KEEP (*(.jcr)) }
  148. .got : { *(.got.plt) *(.got) }
  149. _edata = .;
  150. PROVIDE (edata = .);
  151. .bss : {
  152. __bss_start = .;
  153. *(.dynbss)
  154. *(.bss .bss.* .gnu.linkonce.b.*)
  155. *(COMMON)
  156. /* Align here to ensure that the .bss section occupies space up to
  157. _end. Align after .bss to ensure correct alignment even if the
  158. .bss section disappears because there are no input sections. */
  159. . = ALIGN(32 / 8);
  160. . = ALIGN(32 / 8);
  161. }
  162. __bss_stop = .;
  163. _end = .;
  164. PROVIDE (end = .);
  165. STABS_DEBUG
  166. DWARF_DEBUG
  167. ELF_DETAILS
  168. DISCARDS
  169. }