build: Add support for Bazel to build modules

Add support for modules to be built with Bazel for pineapple and kalama.
Create generic module registering system for multiple targets.

Change-Id: Ib92e4e6b8eaf022d9ba4f66f149c14228238ae21
Signed-off-by: Eric Rosas <[email protected]>

BUILD.bazel

@@ -0,0 +1,52 @@
+package(
+    default_visibility = [
+        "//visibility:public",
+    ],
+)
+
+load("//build/kernel/kleaf:kernel.bzl", "ddk_headers")
+
+ddk_headers(
+    name = "audio_common_headers",
+    hdrs = glob([
+        "include/asoc/*.h",
+        "include/bindings/*.h",
+        "include/dsp/*.h",
+        "include/ipc/*.h",
+        "include/soc/*.h"
+    ]),
+    includes = ["include"]
+)
+ddk_headers(
+    name = "audio_uapi_headers",
+    hdrs = glob([
+        "include/uapi/audio/**/*.h"
+    ]),
+    includes = ["include/uapi/audio"]
+)
+ddk_headers(
+    name = "audio_src_headers",
+    hdrs = glob([
+        "asoc/**/*.h",
+        "dsp/**/*.h",
+        "ipc/**/*.h",
+        "soc/**/*.h"
+    ])
+)
+ddk_headers(
+    name = "audio_configs",
+    hdrs = glob([
+        "config/*.h"
+    ]),
+    includes = ["config"]
+)
+ddk_headers(
+    name = "audio_headers",
+    hdrs = [":audio_common_headers",  ":audio_uapi_headers", ":audio_src_headers", ":audio_configs"]
+)
+
+load(":build/pineapple.bzl", "define_pineapple")
+load(":build/kalama.bzl", "define_kalama")
+
+define_kalama()
+define_pineapple()

audio_modules.bzl

@@ -0,0 +1,371 @@
+load(":module_mgr.bzl", "create_module_registry")
+
+DSP_PATH = "dsp"
+IPC_PATH = "ipc"
+SOC_PATH = "soc"
+ASOC_PATH = "asoc"
+ASOC_CODECS_PATH = ASOC_PATH + "/codecs"
+ASOC_CODECS_LPASS_CDC_PATH = ASOC_CODECS_PATH + "/lpass-cdc"
+
+audio_modules = create_module_registry([":audio_headers"])
+# ------------------------------------ AUDIO MODULE DEFINITIONS ---------------------------------
+# >>>> DSP MODULES <<<<
+audio_modules.register(
+    name = "q6_dlkm",
+    path = DSP_PATH,
+    conditional_srcs = {
+        "CONFIG_SND_SOC_MSM_QDSP6V2_INTF": [
+            "msm-audio-event-notify.c",
+            "q6_init.c",
+        ],
+        "CONFIG_SND_SOC_MSM_QDSP6V2_VM": [
+            "msm-audio-event-notify.c",
+            "msm_audio_ion_vm.c",
+            "q6_init.c",
+        ],
+        "CONFIG_MSM_AVTIMER": [
+            "avtimer.c"
+        ],
+        "CONFIG_XT_LOGGING": [
+            "sp_params.c"
+        ]
+    }
+)
+audio_modules.register(
+    name = "spf_core_dlkm",
+    path = DSP_PATH,
+    config_option = "CONFIG_SPF_CORE",
+    srcs = ["spf-core.c"],
+    conditional_srcs = {
+        "CONFIG_DIGITAL_CDC_RSC_MGR": [
+            "digital-cdc-rsc-mgr.c"
+        ]
+    }
+)
+audio_modules.register(
+    name = "audpkt_ion_dlkm",
+    path = DSP_PATH,
+    config_option = "CONFIG_AUDIO_PKT_ION",
+    srcs = ["msm_audio_ion.c"]
+)
+audio_modules.register(
+    name = "q6_notifier_dlkm",
+    path = DSP_PATH,
+    config_option = "CONFIG_MSM_QDSP6_NOTIFIER",
+    srcs = [
+        "audio_notifier.c",
+        "audio_ssr.c"
+    ],
+)
+audio_modules.register(
+    name = "adsp_loader_dlkm",
+    path = DSP_PATH,
+    config_option = "CONFIG_MSM_ADSP_LOADER",
+    srcs = ["adsp-loader.c"],
+)
+audio_modules.register(
+    name = "audio_prm_dlkm",
+    path = DSP_PATH,
+    config_option = "CONFIG_AUDIO_PRM",
+    srcs = ["audio_prm.c"],
+)
+audio_modules.register(
+    name = "q6_pdr_dlkm",
+    path = DSP_PATH,
+    config_option = "CONFIG_MSM_QDSP6_PDR",
+    srcs = ["audio_pdr.c"]
+)
+# >>>> IPC MODULES <<<<
+audio_modules.register(
+    name = "gpr_dlkm",
+    path = IPC_PATH,
+    config_option = "CONFIG_MSM_QDSP6_GPR_RPMSG",
+    srcs = ["gpr-lite.c"],
+)
+audio_modules.register(
+    name = "audio_pkt_dlkm",
+    path = IPC_PATH,
+    config_option = "CONFIG_AUDIO_PKT",
+    srcs = ["audio-pkt.c"],
+)
+# >>>> SOC MODULES <<<<
+audio_modules.register(
+    name = "pinctrl_lpi_dlkm",
+    path = SOC_PATH,
+    config_option = "CONFIG_PINCTRL_LPI",
+    srcs = ["pinctrl-lpi.c"],
+)
+audio_modules.register(
+    name = "swr_dlkm",
+    path = SOC_PATH,
+    config_option = "CONFIG_SOUNDWIRE",
+    srcs = [
+        "regmap-swr.c",
+        "soundwire.c"
+    ]
+)
+audio_modules.register(
+    name = "swr_ctrl_dlkm",
+    path = SOC_PATH,
+    conditional_srcs = {
+        "CONFIG_SOUNDWIRE_WCD_CTRL": [
+            "swr-wcd-ctrl.c"
+        ],
+        "CONFIG_SOUNDWIRE_MSTR_CTRL": [
+            "swr-mstr-ctrl.c"
+        ]
+    },
+)
+audio_modules.register(
+    name = "snd_event_dlkm",
+    path = SOC_PATH,
+    config_option = "CONFIG_SND_EVENT",
+    srcs = ["snd_event.c"]
+)
+# >>>> ASOC MODULES <<<<
+audio_modules.register(
+    name = "machine_dlkm",
+    path = ASOC_PATH,
+    srcs = [
+        "msm_common.c",
+    ],
+    conditional_srcs = {
+        "CONFIG_SND_SOC_SM8150": [
+            "sm8150.c",
+            "machine_815x_init.c"
+        ],
+        "CONFIG_SND_SOC_SM6150": [
+            "sm6150.c",
+            "machine_615x_init.c"
+        ],
+        "CONFIG_SND_SOC_SA6155": [
+            "sa6155.c"
+        ],
+        "CONFIG_SND_SOC_QCS405": [
+            "qcs405.c"
+        ],
+        "CONFIG_SND_SOC_KONA": [
+            "kona.c"
+        ],
+        "CONFIG_SND_SOC_LAHAINA": [
+            "lahaina.c"
+        ],
+        "CONFIG_SND_SOC_WAIPIO": [
+            "waipio.c"
+        ],
+        "CONFIG_SND_SOC_KALAMA": [
+            "kalama.c"
+        ],
+        "CONFIG_SND_SOC_PINEAPPLE": [
+            "pineapple.c"
+        ],
+        "CONFIG_SND_SOC_HOLI": [
+            "holi.c"
+        ],
+        "CONFIG_SND_SOC_LITO": [
+            "kona.c"
+        ],
+        "CONFIG_SND_SOC_BENGAL": [
+            "bengal.c"
+        ],
+        "CONFIG_SND_SOC_SA8155": [
+            "sa8155.c"
+        ],
+        "CONFIG_SND_SOC_SDX": [
+            "sdx-target.c"
+        ]
+    },
+)
+# >>>> ASOC/CODEC MODULES <<<<
+audio_modules.register(
+    name = "wcd_core_dlkm",
+    path = ASOC_CODECS_PATH,
+    conditional_srcs = {
+        "CONFIG_WCD9XXX_CODEC_CORE": [
+            "wcd9xxx-rst.c",
+            "wcd9xxx-core-init.c",
+            "wcd9xxx-core.c",
+            "wcd9xxx-irq.c",
+            "wcd9xxx-slimslave.c",
+            "wcd9xxx-utils.c",
+            "wcd9335-regmap.c",
+            "wcd9335-tables.c",
+            "msm-cdc-pinctrl.c",
+            "msm-cdc-supply.c",
+            "wcd934x/wcd934x-regmap.c",
+            "wcd934x/wcd934x-tables.c",
+        ],
+        "CONFIG_WCD9XXX_CODEC_CORE_V2": [
+            "wcd9xxx-core-init.c",
+            "msm-cdc-pinctrl.c",
+            "msm-cdc-supply.c",
+        ],
+        "CONFIG_SND_SOC_WCD_IRQ": [
+            "wcd-irq.c"
+        ]
+    }
+)
+audio_modules.register(
+    name = "mbhc_dlkm",
+    path = ASOC_CODECS_PATH,
+    config_option = "CONFIG_SND_SOC_WCD_MBHC",
+    srcs = ["wcd-mbhc-v2.c"],
+    conditional_srcs = {
+        "CONFIG_SND_SOC_WCD_MBHC_ADC": [
+            "wcd-mbhc-adc.c"
+        ],
+        "CONFIG_SND_SOC_WCD_MBHC_LEGACY": [
+            "wcd-mbhc-legacy.c"
+        ]
+    },
+)
+audio_modules.register(
+    name = "swr_dmic_dlkm",
+    path = ASOC_CODECS_PATH,
+    config_option = "CONFIG_SND_SOC_SWR_DMIC",
+    srcs = ["swr-dmic.c"]
+)
+audio_modules.register(
+    name = "wcd9xxx_dlkm",
+    path = ASOC_CODECS_PATH,
+    config_option = "CONFIG_SND_SOC_WCD9XXX_V2",
+    srcs = [
+        "wcdcal-hwdep.c",
+        "wcd9xxx-soc-init.c",
+        "audio-ext-clk-up.c"
+    ],
+    conditional_srcs = {
+        "CONFIG_WCD9XXX_CODEC_CORE": {
+            True: [
+                "wcd9xxx-common-v2.c",
+                "wcd9xxx-resmgr-v2.c",
+                "wcd-dsp-utils.c",
+                "wcd-dsp-mgr.c",
+            ],
+            False: [
+                "wcd-clsh.c"
+            ]
+        }
+    }
+)
+audio_modules.register(
+    name = "swr_haptics_dlkm",
+    path = ASOC_CODECS_PATH,
+    config_option = "CONFIG_SND_SWR_HAPTICS",
+    srcs = ["swr-haptics.c"]
+)
+audio_modules.register(
+    name = "stub_dlkm",
+    path = ASOC_CODECS_PATH,
+    config_option = "CONFIG_SND_SOC_MSM_STUB",
+    srcs = ["msm_stub.c"]
+)
+audio_modules.register(
+    name = "hdmi_dlkm",
+    path = ASOC_CODECS_PATH,
+    config_option = "CONFIG_SND_SOC_MSM_HDMI_CODEC_RX",
+    srcs = ["msm_hdmi_codec_rx.c"],
+    deps = ["//vendor/qcom/opensource/mm-drivers:%b_mm_drivers"]
+)
+# >>>> ASOC/CODECS/LPASS-CDC MODULES <<<<
+audio_modules.register(
+    name = "lpass_cdc_dlkm",
+    path = ASOC_CODECS_LPASS_CDC_PATH,
+    config_option = "CONFIG_SND_SOC_LPASS_CDC",
+    srcs = [
+        "lpass-cdc.c",
+        "lpass-cdc-comp.c",
+        "lpass-cdc-utils.c",
+        "lpass-cdc-regmap.c",
+        "lpass-cdc-tables.c",
+        "lpass-cdc-clk-rsc.c",
+    ],
+)
+audio_modules.register(
+    name = "lpass_cdc_wsa_macro_dlkm",
+    path = ASOC_CODECS_LPASS_CDC_PATH,
+    config_option = "CONFIG_LPASS_CDC_WSA_MACRO",
+    srcs = ["lpass-cdc-wsa-macro.c"]
+)
+audio_modules.register(
+    name = "lpass_cdc_wsa2_macro_dlkm",
+    path = ASOC_CODECS_LPASS_CDC_PATH,
+    config_option = "CONFIG_LPASS_CDC_WSA2_MACRO",
+    srcs = ["lpass-cdc-wsa2-macro.c"]
+)
+audio_modules.register(
+    name = "lpass_cdc_va_macro_dlkm",
+    path = ASOC_CODECS_LPASS_CDC_PATH,
+    config_option = "CONFIG_LPASS_CDC_VA_MACRO",
+    srcs = ["lpass-cdc-va-macro.c"]
+)
+audio_modules.register(
+    name = "lpass_cdc_rx_macro_dlkm",
+    path = ASOC_CODECS_LPASS_CDC_PATH,
+    config_option = "CONFIG_LPASS_CDC_RX_MACRO",
+    srcs = ["lpass-cdc-rx-macro.c"],
+)
+audio_modules.register(
+    name = "lpass_cdc_tx_macro_dlkm",
+    path = ASOC_CODECS_LPASS_CDC_PATH,
+    config_option = "CONFIG_LPASS_CDC_TX_MACRO",
+    srcs = ["lpass-cdc-tx-macro.c"]
+)
+# >>>> WSA883X MODULE <<<<
+audio_modules.register(
+    name = "wsa883x_dlkm",
+    path = ASOC_CODECS_PATH + "/wsa883x",
+    config_option = "CONFIG_SND_SOC_WSA883X",
+    srcs = [
+        "wsa883x.c",
+        "wsa883x-regmap.c",
+        "wsa883x-tables.c",
+    ],
+)
+# >>>> WSA884X MODULE <<<<
+audio_modules.register(
+    name = "wsa884x_dlkm",
+    path = ASOC_CODECS_PATH + "/wsa884x",
+    config_option = "CONFIG_SND_SOC_WSA884X",
+    srcs = [
+        "wsa884x.c",
+        "wsa884x-regmap.c",
+        "wsa884x-tables.c",
+    ]
+)
+# >>>> WCD938X MODULES <<<<
+audio_modules.register(
+    name = "wcd938x_dlkm",
+    path = ASOC_CODECS_PATH + "/wcd938x",
+    config_option = "CONFIG_SND_SOC_WCD938X",
+    srcs = [
+        "wcd938x.c",
+        "wcd938x-regmap.c",
+        "wcd938x-tables.c",
+        "wcd938x-mbhc.c",
+    ]
+)
+audio_modules.register(
+    name = "wcd938x_slave_dlkm",
+    path = ASOC_CODECS_PATH + "/wcd938x",
+    config_option = "CONFIG_SND_SOC_WCD938X_SLAVE",
+    srcs = ["wcd938x-slave.c"]
+)
+# >>>> WCD939X MODULES <<<<
+audio_modules.register(
+    name = "wcd939x_dlkm",
+    path = ASOC_CODECS_PATH + "/wcd939x",
+    config_option = "CONFIG_SND_SOC_WCD939X",
+    srcs = [
+        "wcd939x.c",
+        "wcd939x-regmap.c",
+        "wcd939x-tables.c",
+        "wcd939x-mbhc.c",
+    ]
+)
+audio_modules.register(
+    name = "wcd939x_slave_dlkm",
+    path = ASOC_CODECS_PATH + "/wcd939x",
+    config_option = "CONFIG_SND_SOC_WCD939X_SLAVE",
+    srcs = ["wcd939x-slave.c"]
+)

build/kalama.bzl

@@ -0,0 +1,55 @@
+load(":audio_modules.bzl", "audio_modules")
+load(":module_mgr.bzl", "define_consolidate_gki_modules")
+
+def define_kalama():
+    define_consolidate_gki_modules(
+        target = "kalama",
+        registry = audio_modules,
+        modules = [
+            "q6_dlkm",
+            "spf_core_dlkm",
+            "audpkt_ion_dlkm",
+            "q6_notifier_dlkm",
+            "adsp_loader_dlkm",
+            "audio_prm_dlkm",
+            "q6_pdr_dlkm",
+            "gpr_dlkm",
+            "audio_pkt_dlkm",
+            "pinctrl_lpi_dlkm",
+            "swr_dlkm",
+            "swr_ctrl_dlkm",
+            "snd_event_dlkm",
+            "machine_dlkm",
+            "wcd_core_dlkm",
+            "mbhc_dlkm",
+            "swr_dmic_dlkm",
+            "wcd9xxx_dlkm",
+            "swr_haptics_dlkm",
+            "stub_dlkm",
+            "hdmi_dlkm",
+            "lpass_cdc_dlkm",
+            "lpass_cdc_wsa_macro_dlkm",
+            "lpass_cdc_wsa2_macro_dlkm",
+            "lpass_cdc_va_macro_dlkm",
+            "lpass_cdc_rx_macro_dlkm",
+            "lpass_cdc_tx_macro_dlkm",
+            "wsa883x_dlkm",
+            "wsa884x_dlkm",
+            "wcd938x_dlkm",
+            "wcd938x_slave_dlkm"
+        ],
+        config_options = [
+            "CONFIG_SND_SOC_KALAMA",
+            "CONFIG_SND_SOC_MSM_QDSP6V2_INTF",
+            "CONFIG_MSM_QDSP6_SSR",
+            "CONFIG_DIGITAL_CDC_RSC_MGR",
+            "CONFIG_SOUNDWIRE_MSTR_CTRL",
+            "CONFIG_SWRM_VER_2P0",
+            "CONFIG_WCD9XXX_CODEC_CORE_V2",
+            "CONFIG_MSM_CDC_PINCTRL",
+            "CONFIG_SND_SOC_WCD_IRQ",
+            "CONFIG_SND_SOC_WCD9XXX_V2",
+            "CONFIG_SND_SOC_WCD_MBHC_ADC",
+            "CONFIG_MSM_EXT_DISPLAY",
+        ]
+    )

build/pineapple.bzl

@@ -0,0 +1,57 @@
+load(":audio_modules.bzl", "audio_modules")
+load(":module_mgr.bzl", "define_consolidate_gki_modules")
+
+def define_pineapple():
+    define_consolidate_gki_modules(
+        target = "pineapple",
+        registry = audio_modules,
+        modules = [
+            "q6_dlkm",
+            "spf_core_dlkm",
+            "audpkt_ion_dlkm",
+            "q6_notifier_dlkm",
+            "adsp_loader_dlkm",
+            "audio_prm_dlkm",
+            "q6_pdr_dlkm",
+            "gpr_dlkm",
+            "audio_pkt_dlkm",
+            "pinctrl_lpi_dlkm",
+            "swr_dlkm",
+            "swr_ctrl_dlkm",
+            "snd_event_dlkm",
+            "machine_dlkm",
+            "wcd_core_dlkm",
+            "mbhc_dlkm",
+            "swr_dmic_dlkm",
+            "wcd9xxx_dlkm",
+            "swr_haptics_dlkm",
+            "stub_dlkm",
+            "hdmi_dlkm",
+            "lpass_cdc_dlkm",
+            "lpass_cdc_wsa_macro_dlkm",
+            "lpass_cdc_wsa2_macro_dlkm",
+            "lpass_cdc_va_macro_dlkm",
+            "lpass_cdc_rx_macro_dlkm",
+            "lpass_cdc_tx_macro_dlkm",
+            "wsa883x_dlkm",
+            "wsa884x_dlkm",
+            "wcd938x_dlkm",
+            "wcd938x_slave_dlkm",
+            "wcd939x_dlkm",
+            "wcd939x_slave_dlkm"
+        ],
+        config_options = [
+            "CONFIG_SND_SOC_PINEAPPLE",
+            "CONFIG_SND_SOC_MSM_QDSP6V2_INTF",
+            "CONFIG_MSM_QDSP6_SSR",
+            "CONFIG_DIGITAL_CDC_RSC_MGR",
+            "CONFIG_SOUNDWIRE_MSTR_CTRL",
+            "CONFIG_SWRM_VER_2P0",
+            "CONFIG_WCD9XXX_CODEC_CORE_V2",
+            "CONFIG_MSM_CDC_PINCTRL",
+            "CONFIG_SND_SOC_WCD_IRQ",
+            "CONFIG_SND_SOC_WCD9XXX_V2",
+            "CONFIG_SND_SOC_WCD_MBHC_ADC",
+            "CONFIG_MSM_EXT_DISPLAY",
+        ]
+    )

module_mgr.bzl

@@ -0,0 +1,104 @@
+load("//build/bazel_common_rules/dist:dist.bzl", "copy_to_dist_dir")
+load("//build/kernel/kleaf:kernel.bzl", "kernel_module",
+                                        "kernel_modules_install",
+                                        "ddk_module",
+                                        "ddk_submodule")
+
+def _create_module_conditional_src_map(conditional_srcs):
+    processed_conditional_srcs = {}
+
+    for conditional_src_name in conditional_srcs:
+        conditional_src = conditional_srcs[conditional_src_name]
+
+        if type(conditional_src) == "list":
+            processed_conditional_srcs[conditional_src_name] = { True: conditional_src }
+        else:
+            processed_conditional_srcs[conditional_src_name] = conditional_src
+
+    return processed_conditional_srcs
+
+def _get_module_srcs(module, options, formatter):
+    srcs = [] + module.srcs
+    module_path = "{}/".format(module.path) if module.path else ""
+
+    for option in module.conditional_srcs:
+        is_option_enabled = option in options
+        srcs.extend(module.conditional_srcs[option].get(is_option_enabled, []))
+
+    return ["{}{}".format(module_path, formatter(src)) for src in srcs]
+
+def _combine_target_module_options(modules, config_options):
+    all_options = {option: True for option in config_options}
+    all_options = all_options | {module.config_option: True for module in modules if module.config_option}
+
+    return all_options
+
+def create_module_registry(hdrs = []):
+    module_map = {}
+
+    def register(name, path = None, config_option = None, srcs = [], conditional_srcs = {}, deps = []):
+        module_map[name] = struct(
+            name = name,
+            path = path,
+            srcs = srcs,
+            conditional_srcs = _create_module_conditional_src_map(conditional_srcs),
+            config_option = config_option,
+            deps = deps,
+        )
+
+    return struct(
+        module_map = module_map,
+        hdrs = hdrs,
+        register = register,
+        get = module_map.get,
+    )
+
+def define_target_modules(target, variant, registry, modules, config_options = []):
+    formatter = lambda s : s.replace("%t", target)\
+                            .replace("%v", variant)\
+                            .replace("%b", "{}_{}".format(target, variant))
+    kernel_build = "{}_{}".format(target, variant)
+    kernel_build_label = "//msm-kernel:{}".format(kernel_build)
+    modules = [registry.get(module_name) for module_name in modules]
+    options = _combine_target_module_options(modules, config_options)
+    headers = ["//msm-kernel:all_headers"] + registry.hdrs
+    all_module_rules = []
+
+    for module in modules:
+        rule_name = "{}_{}".format(kernel_build, module.name)
+        srcs = _get_module_srcs(module, options, formatter)
+        deps = headers + [formatter(dep) for dep in module.deps]
+
+        if not srcs:
+            continue
+
+        ddk_submodule(
+            name = rule_name,
+            srcs = srcs,
+            out = "{}.ko".format(module.name),
+            deps = deps,
+            local_defines = options.keys(),
+        )
+
+        all_module_rules.append(rule_name)
+
+    ddk_module(
+        name = "{}_modules".format(kernel_build),
+        kernel_build = kernel_build_label,
+        deps = all_module_rules
+    )
+
+    copy_to_dist_dir(
+        name = "{}_modules_dist".format(kernel_build),
+        data = [":{}_modules".format(kernel_build)],
+        dist_dir = "out/target/product/{}/dlkm/lib/modules/".format(target),
+        flat = True,
+        wipe_dist_dir = False,
+        allow_duplicate_filenames = False,
+        mode_overrides = {"**/*": "644"},
+        log = "info"
+    )
+
+def define_consolidate_gki_modules(target, registry, modules, config_options = []):
+    define_target_modules(target, "consolidate", registry, modules, config_options)
+    define_target_modules(target, "gki", registry, modules, config_options)